Excel: Fragen und Probleme

[Chi Lu Jung]

Hallo Shotgun und Excel-Einsteiger,

auf dieser Webseite findet ihr eine umfangreiche Linkliste mit Verweisen auf Excel-Grundlagenkursen und Excel-Beispielen. Ich denke, da ist für jeden etwas dabei.

[Buk]

hallo chi lu jung,

... ich blamiere mich jetzt mal total, aber ich rechne trotzdem mit deiner unterstützung bei diesem problemchen:

ich möchte eine ergebnispermanenz in excel erstellen.

"l" sei -1, "ll" sei 1, "h" sei -100, "hh" sei 100

ich habe mir für diese trivialität die wenn-abfrage ausgesucht, doch excel macht mir bei folgender formel einen strich durch die rechnung:

=WENN(A1="l";-1;WENN(A1="ll";1));wenn(a1="h";-100;wenn(a1="hh";100))

ich bekomme dann den ausdruck #wert!

was hat buk verbockt???

vielen dank im voraus

buk

[Shotgun]

Hi Buk,

bin auch noch kein Excel-Experte, aber vielleicht hilft dir das:

=wenn(oder(a1="I";-1;a1="II";1;a1="h";-100;a1="hh";100;)"")

Vor allem hast du eines vergessen, nämlich was Excel machen soll wenn keine deiner Bedingungen zutreffen. Ich habe dafür "" eingesetzt, also nichts.

Hoffe, das Pulver hilft dir weiter

Shotgun

[Shotgun]

Correction, das Semikolon vor den"" muß hinter der Klammer stehen!!!

Sonst zündet das Pulver nicht

Shotgun

[Buk]

hi shotgun,

...hast du die formel überprüft?

nach deiner anweisung...

=WENN(ODER(A1="l";-1;A1="ll";1;A1="h";-100;A1="hh";100);"")

... bekomme ich keinen wert, also zelle b1 bleibt leer

gruß

buk

[Chi Lu Jung]

Hallo Buk,

der Ansatz war schon nicht schlecht. Du hast nur die Klammern mal falsch gesetzt. Du mußt immer darauf achten, die Bedingungen ineinander zu verschachteln!

Hier mal mein Vorschlag

=WENN(A1>"";WENN(A1="I";-1;WENN(A1="II";1;WENN(A1="h";-100;WENN(A1="hh";100;0))));"")

Ich hoffe, es hilft dir weiter.

Hallo Shotgun,

ich muss dir leider sagen, deine Formel ergibt keinen Sinn

Im Oder-Teil kannst du Bedingungen zusammenfassen - wenn dann eine von denen eintrifft, dann wird EINE Anweisung ausgeführt. Buk benötigt aber für verschiedene Bedingungen VERSCHIEDENE Anweisungen.

[Buk]

hallo ihr zwei,

nicht streiten, ich nehme jeden vorschlag gerne an, wenn ich dadurch die lösung hinbekomme, ächz

also, chin, ich habe deine formel kopiert, aber für die variablen l und ll kriege ich nur den wert 0; bei h und hh funzt es aber schon.

liegt es an den berüchtigten steuerzeichen?

please help

little doof buk

[Chi Lu Jung]

Hallo Buk,

ich habe I und II als großes "i" interpretiert. Das war offentsichtlich falsch. Welches Zeichen hast du den verwendet?

Du kannst es doch ganz einfach ändern, in deim du entweder in deiner Formel I verwendest oder in meiner Formel dein Zeichen.

[Shotgun]

@Chi

Hast natürlich Recht, kommt davon wenn man mal besonders Schlau sein will und das "mal eben" aus dem Handgelenk machen will.

War kein zündendes Pulver

Shotgun

[Buk]

hallo chin,

jetzt ist alles gut

... kleiner fehler, große wirkung - in excel wird I als l dargestellt...

vielen vielen dank

danke auch an shotgun, dem schnellsten mann in tombstone

ich sehe, ich muß noch ne menge excelizen...

gruß

buk

[Buk]

hallo excelaner,

ich habe meine schachtel-formel bezogen auf eine zelle ein wenig aufgebläht.

ich stelle fest, dass man nicht unendlich viele bedingungen verschachteln kann...

aber wieviele sind es denn genau?

nach sieben argumenten scheint excel97 nicht mehr zu wollen, oder doch?

=WENN(A2>"";WENN(A2="l";-1;WENN(A2="ll";1;WENN(A2="h";-100;WENN(A2="hh";100;WENN(A2="H";200;WENN(A2="V";-200;WENN(A2="o";0;0)))))));"")

... ich hätte noch einige angeführt, aber ging nit

... schon wieder was falsch gemacht? kann man tricksen??

buk, allein zu haus

[Shotgun]

Hi Buk,

stimmt, nach 7 Wenn-Abfragen ist eigentlich Schluß, aber ein Tip den ich von wenke (der nur Sonntags schreibt) habe: Nach den 7 Abfragen ein + und dann kannst du mit weitern 7 von vorne beginnen. Aber ob man das unendlich weitermachen kann: Nie nicht keine Ahnung.

Also: wenn(sowieso;dann; x 7;sonst)))))))+wenn(bla bla....

Eine andere Möglichkeit: als Sonst-Bedingung eine andere Zelle angeben, in der du dann eben weitere 7 Wenn-Abfragen durchführst.

Also wenn du die ersten 7 z.B. in b3 hast, als letztes eingeben z.B.C3 statt der "" und dort dann die weiteren Abfragen.

Ich hoffe, das war nicht wieder ein Schnellschuß von mir, aber so hat's bei mir geklappt mit einer zu langen Progri-Abfrage in einer Zelle.

Hoffe ist diesmal besseres Pulver

Shotgun

[Chi Lu Jung]

Hallo Buk,

das mit den sieben Wenn-Bedingungen siehst du richtig. Mit einem Trick kann man Excel zu mehr überreden. Aber den Trick möchte ich hier gar nicht darlegen.

Jetzt denkt ihr: "Was für ein Ar......"

Aber bedenkt , wer soll diese Wenn-Bedingungen noch durchschauen. Das ist schlechter Programmierstil und den bringe ich euch nicht bei - das kann ein anderer machen.

Also erlaube ich mir, eine elegante Lösung für dein Problem darzulegen:

Formeln in den Zellen als QuickNotiz " wurden durch ' ersetzt
	A	B	C	D	E
1	Signal	Plus/Minus		Signal	Plus/Minus
2	I	-1		I	-1
3	II	1		II	1
4	h	-100		h	-100
5	hh	100		hh	100
6	H	-100		H	200
7	V	-200		V	-200
8				o	0

Und hier nur die Formeln:

	A	B	C	D	E
1	Signal	Plus/Minus		Signal	Plus/Minus
2	I	=WENN(A2>"";SVERWEIS(A2;Signalwerte;2;FALSCH);"")		I	-1
3	II	=WENN(A3>"";SVERWEIS(A3;Signalwerte;2;FALSCH);"")		II	1
4	h	=WENN(A4>"";SVERWEIS(A4;Signalwerte;2;FALSCH);"")		h	-100
5	hh	=WENN(A5>"";SVERWEIS(A5;Signalwerte;2;FALSCH);"")		hh	100
6	H	=WENN(A6>"";SVERWEIS(A6;Signalwerte;2;FALSCH);"")		H	200
7	V	=WENN(A7>"";SVERWEIS(A7;Signalwerte;2;FALSCH);"")		V	-200
8		=WENN(A8>"";SVERWEIS(A8;Signalwerte;2;FALSCH);"")		o	0

Der hellblaue Bereich ist mit dem Namen "Signalwerte" belegt. Somit kann man mit SVERWEIS aufgrund des Wertes in Spalte "A" den entsprechenden Wert in den "Signalwerten" suchen. Vorteil der Lösung ist neben der Übersichtlichkeit auch die beliebige Erweiterbarkeit der Tabelle. Wenn neues Signal dazukommt, einfach das Signal mit Plus/Minus Wert eintragen und den Namen "Signalwerte" auf den erweiterten Bereich anpassen.

Ich hoffe, ich konnte dir etwas helfen.

Hier kannst du den Befehl SVERWEIS im Detail nachlesen.

bearbeitet Januar 31, 2004 von Chi Lu Jung

[Buk]

hallo ihr zwei tapferen recken!!

...hm, hm, hm... ich komme gerade aus der sauna. alles wasser raus und ein bißchen hirn vielleicht mit.

muß eure infos noch verarbeiten. jetzt erst einmal heia heia.

ich werde beide lösungsvorschläge probieren und euch unterrichten, wies gelaufen ist.

danke euch beiden, ihr seid richtige nuggets

shotgun, ich bin gespannt wie deine mega-progri aussieht. auf dass sie niemals platzen möge!

chin, du bist der absolute wahnsinnsmacker

sorry für die schmalzstulle, aber das mußte ich nochmal so sagen.

habt euch wohl

buk, near paradise

[Wenke]

@Buk

Ich kann Chi Lu Jung nur zu stimmen.

Die von mir genannte lösung ist nur eine Krücke.

Der Sverweis ist nicht so schwierig wie es aussieht.

Die Lösung mit dem Sverweis ist nicht nur eleganter,

er ist vorallem viel flexibler. Es lassen sich z.b mehrere Spalten anfügen.

Dann brauchst du nur die Suchspalte verändern um verschiedene Abfragemöglichkeiten zu haben.

@Chi Lu Jung

Jetzt denkt ihr: "Was für ein Ar......"

Nein das bist du nicht.

Bessere Lösungen sollten immer angeboten werden.

[Buk]

hallo chi lu jung,

ich habe deine 2. tabelle versucht nachzubauen...

ich sage es gleich, ich hab mich noch nicht mit sverweis beschäftigt. ich möchte erst einmal sehen, ob das alles fluppt, was ich nach euren anweisungen nachbaue.

bitte nicht steinigen, aber gerade am anfang mit excelizen will man doch schnell erfolge sehen. ich kann dann auch verstehen, dass man auf biegen und brechen etwas hinbekommen möchte...

mit shotguns hardcore-Kiffer ging es sofort

thanks, shotgun

also: wenn ich die erste zeile der 2. tabelle so nachbaue, bekomme ich in spalte b den hinweis #name?

ich denke, "signalwerte" müssen noch irgendwo untergebracht werden...

...oder habe ich etwas komplett übersehen?

in jedem fall möchte ich die elegante lösung hinkriegen.

ist klar, irgendwann sind die zellen einfach zu unübersichtlich und man stochert dann nur noch im dunklen.

gruß

buk

[Chi Lu Jung]

Hallo Buk,

freut mich, dass du dich um "elegante" Lösungen bemühst. Mach dies aber nicht auf Biegen oder Brechen, sondern suche dir die Lösung mit der du am Besten klarkommst. Ansonsten macht das Ganze ja keinen Spaß

Nun zu deiner Frage:

Der hellblaue Bereich ist mit dem Namen "Signalwerte" belegt.

Ich hoffe, du hast diesen Satz nicht überlesen. Wenn ja, dann hier noch einmal im Klartext. Damit die Formel SVERWEIS funktioniert, muss es natürlich einen Bereich mit den Namen "Signalwerte" geben. In meiner Tabelle ist dies der hellblau hinterlegte Bereich bzw der Bereich D2:E8. Ich hoffe, du kannst mit der Bennung von Bereichen etwas anfangen. Wenn nicht, hier eine Kurzanleitung.

1) Den Bereich D2:E8 markieren.

2) In der Bearbeitungsleiste steht ja ganz links immer die Zelle mit Spalte / Zeilennummer. Nach der Makierung steht hier nun "D2". Nun diese einfach mit den Namen "Signalwerte" überschreiben und per Enter-Taste bestätigen.

Nun müßte es klappen. Namen kannst du auch über das Menü "Einfügen -> Namen -> Definieren ..." erfassen.

[Chi Lu Jung]

Hallo Buk,

zum besseren Veständnis hier noch ein Screenshot:

[Wenke]

@Buk

Auf die Gefahr hin das ich Chi Lu Jung ins Handwerk pfusche:

Chi hat Namen vergeben. Deshalb die Fehlermeldung.

Wenn du die Tabelle von Chi nach baust und keine Namen vergeben hast gib folgende Formel in die Zelle "B2" ein:

Chi'Formel

=WENN(A2>"";SVERWEIS(A2;Signalwerte;2;FALSCH);"")

Neue Formel:

=WENN(A2>"";SVERWEIS(A2;$D$2:$E$8;2;FALSCH);"")

zum Einsetzen

=WENN(A2>0;SVERWEIS(A2;$D$2:$E$8;2;FALSCH);"")

die anderen Formeln genau so ändern.

Beste Grüße und viel Glück

Wenke

[Buk]

oh, chin...

... ich gelobe hoch und heilig in zukunft erst dein posting zur gänze zu lesen und mich durchzukauen!!! das ist natürlich DIE lösung.

danke für deine geduld mit mir dösbaddel

ja, jetzt ist alles klar, danke auch an wenke

gruß

buk

[Chi Lu Jung]

Hallo Buk,

ist schon ok. Und ich gelobe, in Zukunft meine Postings klarer und verständlicher zu gestalten. Wenn ich schon mit dem Anspruch hier auftrete, ein verständliche Einführung in die Excel-Programmierung zu geben, so muss ich dies auch so tun, dass man es auf Anhieb verstehen kann. B:

[Buk]

hallo chin,

ich habe ein problem mit der erweiterung eines vorher festgelegten bereichs, will sagen, ich habe die letzte tabelle nachgebaut und um weitere signale ergänzt, die ich ebenfalls als signalwerte definiert haben möchte.

wenn ich nun meinen neuen bereich markiere und mit "signalwerte" überschreiben möchte, geht dieses nicht. excel springt sozusagen zurück und zeigt mir den alten bereich an. wenn ich einen neuen namen vergebe, und die formeln entsprechend umändere, ist das kein problem, aber der name "signalwerte" hängt auf dem alten bereich fest.

meine fragen dazu:

1) was läuft verkehrt?

2) kann man bereichsnamen in der liste überschreiben oder löschen?

3) öh... was ist quicknotiz... ? sieht toll aus

danke im voraus

buk

[Chi Lu Jung]

Hallo Buk,

Namen kannst du nur über das Menü "Einfügen -> Namen -> Definieren" verwalten. In der Bearbeitungsleiste kannst du nur die Namen anlegen. Also bitte übers Menü das Verwaltungsfenster für die Namen aufrufen und dort den Namen "Signalwerte" anwählen. Dann in der untersten Zeile "Bezieht sich auf:" entsprechend deinem neuem Bereich anpassen. Noch ein Tipp: die Excel-Hilfe gibt zu solchen Themen erschöpfend Auskunft

QuickNotiz ist der Text, der aufgeblendet wird, wenn du in der Tabelle über ein Feld mit einer Formel gehst.

Ich hoffe, ich konnte dir helfen ... bis demnächst im gleichen Kino

[David Cooper]

Hi Chi,

danke für deine Hilfe bezüglich Tottermanns System!

Ich habe aber wieder ein Mal ein Problem - ich hatte diese Frage auch heute schon in einem anderen Thread gepostet. Ich möchte gerne mit einem Excel-Programm die Wurfweiten zwischen zwei Roulette Ziffern abfragen!

Ließe sich das mit so einer Tabelle als Verweisfunktion abfragen!

WW steht hierbei für eine Zahl (muss noch eingesetzt werden)!

Aber bisher dachte ich, dass man mit Verweis-Funktionen nur ein Suchkriterium angegeben kann???

Oder?? (Idee kommt mir gerade jetzt) man setzt als Spaltennummer auch eine gefallene Zahl ein! - Das könnte funktionieren, oder??

0 0 1 2 3 4 5 6 ... ...

1 WW WW WW WW WW WW WW WW WW

2 WW WW WW WW WW WW WW WW WW

3 WW WW WW WW WW WW WW WW WW

4 WW WW WW WW WW WW WW WW WW

5 WW WW WW WW WW WW WW WW WW

6 WW WW WW WW WW WW WW WW WW

7 WW WW WW WW WW WW WW WW WW

... WW WW WW WW WW WW WW WW WW

... WW WW WW WW WW WW WW WW WW

Vielen Dank im Voraus!

Ich glaube jetzt hab ich es!

Es ist manchmal doch hilfreich, wenn man sein Problem verfasst!

Gruß

David Cooper

[Chi Lu Jung]

Hallo David,

so kompliziert muss man es gar nicht machen.

Du brauchst einfach nur eine Auflistung der Kesselzahlen, beginnen wir mal bei 0. Dann kannst du mit der Funktion "VERGLEICH" die Position einer Zahl bestimmen. Die Differenz zwischen den beiden Positionen zweier gefallener Zahlen ist dann die Wurfweite. Da ich die Zahlen von 0 nach rechts aufgelistet habe, stellt die Differenz die Wurfweite Rechts dar. Ziehen wir nun von 37 (Zahlen) die Wurfweite Rechts ab, bekommen wir die Wurfweite nach Links.

Hier die Legende mit der Auflistung der Kesselzahlen. Der hellblaue Bereich (Bereich von A2:A75) ist mit den Namen "KZahlen" versehen.

Formeln in den Zellen als QuickNotiz " wurden durch ' ersetzt
	A
1	Kessel
2	0
3	32
4	15
5	19
6	4
7	21
8	2
9	25
10	17
11	34
12	6
13	27
14	13
15	36
16	11
17	30
18	8
19	23
20	10
21	5
22	24
23	16
24	33
25	1
26	20
27	14
28	31
29	9
30	22
31	18
32	29
33	7
34	28
35	12
36	35
37	3
38	26
39	0
40	32
41	15
42	19
43	4
44	21
45	2
46	25
47	17
48	34
49	6
50	27
51	13
52	36
53	11
54	30
55	8
56	23
57	10
58	5
59	24
60	16
61	33
62	1
63	20
64	14
65	31
66	9
67	22
68	18
69	29
70	7
71	28
72	12
73	35
74	3
75	26

Hier die Ermittlung der Wurfweiten:

Formeln in den Zellen als QuickNotiz " wurden durch ' ersetzt
	A	B	C	D
4			Wurfweiten
5	Coups	Position	Rechts	Links
6	33	23
7	14	26	3	34
8	32	2	24	13
9	32	2	0	37
10	7	32	30	7
11	33	23	9	28
12	30	16	7	30
13	11	15	1	36
14	33	23	8	29
15	30	16	7	30
16	12	34	18	19
17	12	34	0	37

Dazu servieren wir noch die Formeln, dann sind auch die Excel-Freaks glücklich:

	A	B	C	D
4			Wurfweiten
5	Coups	Position	Rechts	Links
6	33	=WENN(ISTZAHL(A6);VERGLEICH($A6;KZahlen;0);"")
7	14	=WENN(ISTZAHL(A7);VERGLEICH($A7;KZahlen;0);"")	=WENN(ISTZAHL(B7);WENN(B7>B6;B7-B6;B6-B7);"")	=WENN(ISTZAHL(C7);37-C7;"")
8	32	=WENN(ISTZAHL(A8);VERGLEICH($A8;KZahlen;0);"")	=WENN(ISTZAHL(B8);WENN(B8>B7;B8-B7;B7-B8);"")	=WENN(ISTZAHL(C8);37-C8;"")
9	32	=WENN(ISTZAHL(A9);VERGLEICH($A9;KZahlen;0);"")	=WENN(ISTZAHL(B9);WENN(B9>B8;B9-B8;B8-B9);"")	=WENN(ISTZAHL(C9);37-C9;"")
10	7	=WENN(ISTZAHL(A10);VERGLEICH($A10;KZahlen;0);"")	=WENN(ISTZAHL(B10);WENN(B10>B9;B10-B9;B9-B10);"")	=WENN(ISTZAHL(C10);37-C10;"")
11	33	=WENN(ISTZAHL(A11);VERGLEICH($A11;KZahlen;0);"")	=WENN(ISTZAHL(B11);WENN(B11>B10;B11-B10;B10-B11);"")	=WENN(ISTZAHL(C11);37-C11;"")
12	30	=WENN(ISTZAHL(A12);VERGLEICH($A12;KZahlen;0);"")	=WENN(ISTZAHL(B12);WENN(B12>B11;B12-B11;B11-B12);"")	=WENN(ISTZAHL(C12);37-C12;"")
13	11	=WENN(ISTZAHL(A13);VERGLEICH($A13;KZahlen;0);"")	=WENN(ISTZAHL(B13);WENN(B13>B12;B13-B12;B12-B13);"")	=WENN(ISTZAHL(C13);37-C13;"")
14	33	=WENN(ISTZAHL(A14);VERGLEICH($A14;KZahlen;0);"")	=WENN(ISTZAHL(B14);WENN(B14>B13;B14-B13;B13-B14);"")	=WENN(ISTZAHL(C14);37-C14;"")
15	30	=WENN(ISTZAHL(A15);VERGLEICH($A15;KZahlen;0);"")	=WENN(ISTZAHL(B15);WENN(B15>B14;B15-B14;B14-B15);"")	=WENN(ISTZAHL(C15);37-C15;"")
16	12	=WENN(ISTZAHL(A16);VERGLEICH($A16;KZahlen;0);"")	=WENN(ISTZAHL(B16);WENN(B16>B15;B16-B15;B15-B16);"")	=WENN(ISTZAHL(C16);37-C16;"")
17	12	=WENN(ISTZAHL(A17);VERGLEICH($A17;KZahlen;0);"")	=WENN(ISTZAHL(B17);WENN(B17>B16;B17-B16;B16-B17);"")	=WENN(ISTZAHL(C17);37-C17;"")

Die Erklärung der einzelnen Formeln:

=WENN(ISTZAHL(A6);VERGLEICH($A6;KZahlen;0);"")

Über "Vergleich" können wir die Position eines Suchkriteriums in einem Bereich ermitteln. Wir suchen also unsere gefallene Zahl aus Zelle A6 in den Kesselzahlen, also in den Bereich mit den Namen "KZahlen". Der dritte Parameter 0 gibt an, dass Vergleich den ersten Wert findet, der genau gleich dem Suchbegriff ist.

Zur Ermittlung der Wurfweite nach Rechts müssen wir nun die Positionen der beiden gefallenen Zahlen von einander abziehen. Wenn die Position der zuletzt gefallene Zahl (B7) größer ist als die von B6, dann lautet die Rechnung "B7 - B6", ansonsten natürlich umgekehrt.

=WENN(ISTZAHL(B7);WENN(B7>B6;B7-B6;B6-B7);"")

Die Wurfweite nach Links wird dann ganz einfach durch die Rechnung "37 (Zahlen) - Position WW Rechts" ermittelt. Das wars

=WENN(ISTZAHL(C7);37-C7;"")

Als Vorlage habe ich ein Excel-Spreed mit der Berechnung der Wurfweiten angehängt. Ich hoffe, ihr könnt es gebrauchen.